対象の日付かつ特定の列の情報取得①(C列のみ)

技術ブログ

2025.12.172025.12.28

今回は過去の失敗を振り返りHTAからのコードを作成から始めず、まずは直接VBScriptのコードの
作成から始めていこうと思ったので進め方を変更させて頂きたいと思います。
１．前提作業
まずは「サーバー管理台帳」と「実機環境作業手続き申請書」が必要となります。
実機環境作業手続き申請書のファイル：
基本的には「改訂履歴」(１番目)はシートだけを用意しておいてもらえればよいのですが、コードを検証して頂くには「作業手続き申請書」(２番目)のシートが存在した状態で正しい列の状態に揃えてもらわないと正しい動作にはならないのでご注意ください。
1-1．サーバー管理台帳のイメージ
見出しの行が3行目となり、データ情報は「4行目」から「41行目」までとなります。
ファイルの保存の前に「2025/12/20」の日付でフィルタをかけておいてください。

1-2．実行環境作業手続き申請書のイメージ
VBScriptが実行後はH列28行目から該当したものが出力されるようにあっております。

1-3．VBScript実行後のイメージ
サーバー管理台帳で該当する日付があった場合は該当したデータが取得されてH列とM列に
表示されるようになっております
今回の例ではサーバー管理台帳で「2025/12/20」でフィルタが表示されていることが前提です。
この後にいろいろカスタマイズをしていく予定でございますのでご了承ください。

２．実行処理とファイルの保存方法
①ソースコードはこちらをご覧にくださいとをクリックして頂けますとコードが表示されますので
メモ長を起動して貼り付けてください。管理者権限じゃなくても普通に起動してください
②デフォルトの拡張子(.txt)からVBScriptの拡張子(.vbs)をクリック変更してください。
その前の表示はファイル名なのでご自身で好きに決めてください。

'========================================================================
' 変数の設定
'========================================================================
Dim basePath, srcPath, outPath

Dim xlApp, srcBook, srcSheet, outBook, outSheet

Dim targetDate, dataStartRow, lastRow, outRow, r, hitcount

Dim targetText, i

Dim startCopyRow, pasteRow, j

'========================================================================
' 参照元と出力先のファイルの指定してファイルを開く
'========================================================================
basePath = "C:\Users\sasio-tech.SASIO.JP\Documents\作業申請ツール"
srcPath  = basePath & "\sample_001.xlsx"
outPath  = basePath & "\sample_002.xlsx"

Set xlApp = CreateObject("Excel.Application")
xlApp.Visible = False
xlApp.DisplayAlerts = False

Set srcBook = xlApp.Workbooks.Open(srcPath)
Set srcSheet = srcBook.Sheets(1)

Set outBook = xlApp.Workbooks.Open(outPath)
Set outSheet = outBook.Sheets(2)

'========================================================================
' オートフィルタの設定を確認する
'========================================================================
Const xlCellTypeVisible = 12
Const xlUp = -4162

' サンプルコードのための動作確認のため日付を「2025/12/20」を固定化
targetDate = "2025/12/20"
dataStartRow = 4

If srcSheet.AutoFilterMode = False Then
    MsgBox "オートフィルタが設定されていません。"
    srcBook.Close False
    outBook.Close False
    xlApp.Quit
    WScript.Quit
End If

srcSheet.Range("A4").AutoFilter 7, targetDate

On Error Resume Next
srcSheet.Range("G4:G41").SpecialCells xlCellTypeVisible
If Err.Number <> 0 Then
    MsgBox "対象日付のデータがありません。"
    Err.Clear
    srcBook.Close False
    outBook.Close False
    xlApp.Quit
    WScript.Quit
End If
On Error GoTo 0

lastRow = srcSheet.Cells(srcSheet.Rows.Count, "G").End(xlUp).Row

'========================================================================
' 参照元ファイルのC列から出力先ファイルのH列に出力する処理
'========================================================================
hitcount = 0
outRow = 28

For r = dataStartRow To lastRow
    If srcSheet.Rows(r).Hidden = False Then
        If Trim(srcSheet.Cells(r, "G").Value) <> "" Then

            'H列にサーバー管理番号を出力
            outSheet.Cells(outRow, "H").Value = srcSheet.Cells(r, "C").Value

            'M列にサーバー名を出力
            outSheet.Cells(outRow, "M").Value = srcSheet.Cells(r, "C").Value

            'X列に「作業実施日/開始時間」を出力
            outSheet.Cells(outRow, "R").Value = srcSheet.Cells(r, "G").Value
            outSheet.Cells(outRow+1, "R").Value = "9時00分"

            outRow = outRow + 2
            hitcount = hitcount + 1
        End If
    End If
Next

srcBook.Close False
outBook.Save
outBook.Close
xlApp.Quit

ソースコードはこちらをご確認ください+